本图片使用POV-Ray创作.

摘要

此math图片可使用矢量图形重新创建为SVG文件。这具有很多好处；更多信息请参见共享资源:待清理媒体。如果存在此图片的SVG格式，请将其上传，然后将此模板替换为{{vector version available|新图片名称}}。 建议您将SVG命名为“Borromean Rings Illusion.svg”，这样在使用Vector version available（或Vva）模板时就不需要填写新图片名称参数。

许可协议

我，本作品著作权人，释出本作品至公有领域。这适用于全世界。 在一些国家这可能不合法；如果是这样的话，那么： 我无条件地授予任何人以任何目的使用本作品的权利，除非这些条件是法律规定所必需的。

Source

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing, and then cropped and compressed using pngcrush.

#include "colors.inc"

background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -250000>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5/10000
  }

light_source
  {
  <0, 200000, -500000>
  color White
  area_light <50000, 0, 0>, <0, 50000, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }

#declare r_tube = 0.07;  // thickness (radius) of tube

#declare sep = 0.2; // apparent height seperation between crossing rings

#declare shiny = finish {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 7.5
    }

#declare GREEN_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<cos(pi/6),sin(pi/6),0>+<0,.1,0>
  pigment { color rgb <0,0.75,0> }
  finish {shiny}
  }

#declare RED_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<-cos(pi/6),sin(pi/6),0> +<0,.1,0>
  pigment { color rgb <1,0,0> }
  finish {shiny}
  }

#declare BLUE_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<0,-1,0>+<0,.1,0>
  pigment { color rgb <0,0.25,1> }
  finish {shiny}
  }
  
object { RED_TORUS }
object { GREEN_TORUS }
object { BLUE_TORUS }  

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }

plane
  {
  <0,0,-1>, -0.33
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }