维基百科

File:QuantumHarmonicOscillatorAnimation.gif

QuantumHarmonicOscillatorAnimation.gif ‎（300 × 373像素，文件大小：759 KB，MIME类型：image/gif、​循环、​97帧）

摘要

描述
English: A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Schrödinger Equation are shown for the same potential. The horizontal axis is position, the vertical axis is the real part (blue) or imaginary part (red) of the wavefunction. (C,D,E,F) are stationary states (energy eigenstates), which come from solutions to the Time-Independent Schrodinger Equation. (G-H) are non-stationary states, solutions to the Time-Dependent but not Time-Independent Schrödinger Equation. (G) is a randomly-generated superposition of the four states (E-F). H is a "coherent state" ("Glauber state") which somewhat resembles the classical state B.
العربية: مذبذب توافقي في الميكانيكا الكلاسيكية (A-B) وميكانيكا الكم (C-H). في (A-B)، كرة متصلة بنابض (خط رمادي)، تتأرجح ذهابًا وإيابًا. في (C-H)، يعرض حلول الدالة الموجية لمعادلة شرودنغر المعتمدة على الوقت لنفس الإمكانات. المحور الأفقي هو الموضع، والمحور العمودي هو الجزء الحقيقي (الأزرق) أو الجزء التخيلي (الأحمر) من دالة الموجة. (C ،D ،E ،F) هي حالات ثابتة (حالات الطاقة الذاتية)، والتي تأتي من حلول معادلة شرودنغر المستقلة عن الزمن. (G-H) هي حالات غير ثابتة، وهي حلول لمعادلة شرودنغر التي تعتمد على الوقت ولكنها ليست مستقلة عن الوقت. (G) هو تراكب أنشىء عشوائيًا للحالات الأربع (E-F). H هي "حالة متماسكة" ("حالة جلوبر") تشبه إلى حد ما الحالة الكلاسيكية B.
日期
来源 自己的作品
作者 Sbyrnes321 
(* Source code written in Mathematica 6.0 by Steve Byrnes, Feb. 2011. This source code is public domain. *)
(* Shows classical and quantum trajectory animations for a harmonic potential. Assume m=w=hbar=1. *)
ClearAll["Global`*"]
(*** Wavefunctions of the energy eigenstates ***)
psi[n_, x_] := (2^n*n!)^(-1/2)*Pi^(-1/4)*Exp[-x^2/2]*HermiteH[n, x];
energy[n_] := n + 1/2;
psit[n_, x_, t_] := psi[n, x] Exp[-I*energy[n]*t];
(*** A random time-dependent state ***)
SeedRandom[1];
CoefList = Table[Random[]*Exp[2 Pi I Random[]], {n, 0, 4}];
CoefList = CoefList/Norm[CoefList];
Randpsi[x_, t_] := Sum[CoefList[[n + 1]]*psit[n, x, t], {n, 0, 4}];
(*** A coherent state (or "Glauber state") ***)
CoherentState[b_, x_, t_] := Exp[-Abs[b]^2/2] Sum[b^n*(n!)^(-1/2)*psit[n, x, t], {n, 0, 15}];
(*** Make the classical plots...a red ball anchored to the origin by a gray spring. ***)
classical1[t_, max_] := ListPlot[{{max Cos[t], 0}}, PlotStyle -> Directive[Red, AbsolutePointSize[15]]];
zigzag[x_] := Abs[(x + 0.25) - Round[x + 0.25]] - .25;
spring[x_, left_, right_] := (.9 zigzag[3 (x - left)/(right - left)])/(1 + Abs[right - left]);
classical2[t_, max_] := Plot[spring[x, -5, max Cos[t]], {x, -5, max Cos[t]}, PlotStyle -> Directive[Gray, Thick]];
classical3 = ListPlot[{{-5, 0}}, PlotStyle -> Directive[Black, AbsolutePointSize[7]]];
classical[t_, max_, label_] := Show[classical2[t, max], classical1[t, max], classical3, 
   PlotRange -> {{-5, 5}, {-1, 1}}, Ticks -> None, Axes -> {False, True}, PlotLabel -> label, AxesOrigin -> {0, 0}];
(*** Put all the plots together ***)
SetOptions[Plot, {PlotRange -> {-1, 1}, Ticks -> None, PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]}}];
MakeFrame[t_] := GraphicsGrid[
   {{classical[t + 2, 1.5, "A"], classical[t, 3, "B"]},
    {Plot[{Re[psit[0, x, t]], Im[psit[0, x, t]]}, {x, -5, 5}, PlotLabel -> "C"], 
     Plot[{Re[psit[1, x, t]], Im[psit[1, x, t]]}, {x, -5, 5}, PlotLabel -> "D"]},
    {Plot[{Re[psit[2, x, t]], Im[psit[2, x, t]]}, {x, -5, 5}, PlotLabel -> "E"], 
     Plot[{Re[psit[3, x, t]], Im[psit[3, x, t]]}, {x, -5, 5}, PlotLabel -> "F"]},
    {Plot[{Re[Randpsi[x, t]], Im[Randpsi[x, t]]}, {x, -5, 5}, PlotLabel -> "G"], 
     Plot[{Re[CoherentState[1, x, t]], Im[CoherentState[1, x, t]]}, {x, -5, 5}, PlotLabel -> "H"]}
    }, Frame -> All, ImageSize -> 300];
output = Table[MakeFrame[t], {t, 0, 4 Pi*96/97, 4 Pi/97}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output]

许可协议

我，本作品著作权人，特此采用以下许可协议发表本作品：
Creative Commons CC-Zero 本作品采用知识共享CC0 1.0 通用公有领域贡献许可协议授权。
采用本宣告发表本作品的人，已在法律允许的范围内，通过在全世界放弃其对本作品拥有的著作权法规定的所有权利（包括所有相关权利），将本作品贡献至公有领域。您可以复制、修改、传播和表演本作品，将其用于商业目的，无需要求授权。

说明

添加一行文字以描述该文件所表现的内容

此文件中描述的项目

描繪內容

文件历史

点击某个日期/时间查看对应时刻的文件。

日期/时间缩⁠略⁠图大小用户备注
当前2011年3月2日 (三) 09:162011年3月2日 (三) 09:16版本的缩略图300 × 373（759 KB）Sbyrnes321Alter spring, to avoid the visual impression that the ball is rotating in a circle around the y-axis through the third dimension.
2011年3月1日 (二) 22:552011年3月1日 (二) 22:55版本的缩略图300 × 373（733 KB）Sbyrnes321Add zigzag spring; shrink image to 300px width; increase frame count to 97.
2011年2月27日 (日) 23:582011年2月27日 (日) 23:58版本的缩略图347 × 432（707 KB）Sbyrnes321Switched from 100 frames to 80 frames, to be under the 12.5-million-pixel limit for animations in wikipedia articles.
2011年2月27日 (日) 23:062011年2月27日 (日) 23:06版本的缩略图347 × 432（887 KB）Sbyrnes321{{Information |Description ={{en|1=A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Sch

以下2个页面使用本文件：

全域文件用途

以下其他wiki使用此文件：

查看本文件的更多全域用途。

取自“https://zh.wikipedia.org/wiki/File:QuantumHarmonicOscillatorAnimation.gif”